OLED SSD01306 (I2C接続)

#include ＜Wire.h＞
uint8_t oledWidth = 128;  // OLEDの幅(ピクセル数)
uint8_t oledPages = 8;    // OLEDのページ数

void setup() {
  Wire.begin();	// Wireクラスの初期化

  // SSD1306の初期化
  Wire.beginTransmission(0x3C);	// I2Cアドレス
  Wire.write(0x00);		// 複数バイトコマンドタグ
  Wire.write(0xC8);		// [C0]/C8:上下の描画方向
  Wire.write(0xA1);		// [A0]/A1:左右の描画方向
  Wire.write(0xA8);Wire.write(0x3F);	// 画面の解像度 [3F]:64Line / 1F:32Line
  Wire.write(0xDA);Wire.write(0x12);	// [12]:Sequential / 02:Alternative
  Wire.write(0xD3);Wire.write(0x00);	// 縦方向のオフセット
  Wire.write(0x40);		// 縦方向の描画開始位置
  Wire.write(0xA6);		// 表示方法 - A7にすると画面反転
   Wire.write(0x8D);Wire.write(0x14);	// OLEDパネルの供給電圧と思われる 14hに設定しないとダメらしい
  Wire.endTransmission();

  // 画面の初期化:黒塗り
  for (uint8_t m = 0; m < oledPages; m++) {
    oledSendCommand3(0xB0 | (m & 0x07) , 0x10 , 0x00) ;

    Wire.beginTransmission(0x3C);
    Wire.write(0x40);	// データタグ
    for (uint8_t x = 0; x < oledWidth; x++) {
      if (Wire.write(0x00) == 0) {
        // --- 送信に失敗したら
        // ArduinoのWireは一度に32バイトまでしか送信できないので33バイト目は必ず送信失敗します。
        // 送信できなかった場合、一旦送信を終了し、再度送信セッションを開いて続けます
        Wire.endTransmission();
        Wire.beginTransmission(0x3C);
        Wire.write(0x40);  // データタグ
        Wire.write(0x00);
      }
    }
    Wire.endTransmission();
  }
  oledSendCommand3(0xB0 , 0x10 , 0x00) ;

  // 画面表示
  Wire.beginTransmission(0x3C);	// I2Cアドレス
  Wire.write(0x80);		// 1バイトコマンドタグ
  Wire.write(0xAF);		// 画面表示
  Wire.endTransmission();
}