ゆるく楽しむプログラミング

Seeeduino XIAOで「学校のチャイム」をタイマー制御してみる:RTC操作

Arduinoには時計機能がないのでI2CインターフェイスのRTC(リアルタイムクロック)ユニットを接続して時刻設定・現在時刻の取得を行います。
使用したRTCはDS1307でRTCとしてはかなりメジャーなモノのようです。
SMTパッケージのICをはんだ付け出来るテクニックがあれば自分で組んだ方が安上がりですがIMDパッケージのICだと単価が高くなるので完成品のDIP化された完成品のユニットを買った方が安上がりです。
【割と重要】RTCユニット使用時の注意

RTCユニットの接続

I2Cインターフェイスは複数のスレーブを同一ラインに接続できますので並べて繋げばOK


RTCの設定と時刻の読み出し

今回はRTCをI2Cインターフェイスを制御するWire関数で操作しています。
時刻は8バイトの2進化10進数として取得できます。
2進化10進数とは
0~Fまでの16進数のうち、0~9までしか使わず10進数とみなす方法)
Ex. 10進数の23は16進数では 0x17 になるが 0x23 として使用する。
  16進数の0x23は10進数では10進数では35だけど23として使用する。

読みだした時刻はOLEDディスプレイに表示します。


#include 
#include 

// RTC デバイスアドレス(スレーブ)
byte RTC_ADDRESS = 0x68;  // 2進数 1101000

// RTCのレジスタテーブル(8byte)
int RegTbl[8];
int i;

// 表示用Buffer
char dispStr[20] ;
static char *youbi[] = {"Sun","Man","Tue","Wed","Thu","Fri","Sat" } ;

// 2進化10進数(BCD)を10進数に変換
byte BCDtoDec(byte value) {
  return ((value >> 4) * 10) + (value & 0x0F) ;
}

void setup(){
  // ===== RTCの初期化 =====
  
  // マスタとしてI2Cバスに接続する
  Wire.begin();
 
  // I2Cスレーブに対して送信処理を開始する
  Wire.beginTransmission(RTC_ADDRESS);
 
  // レジスタのアドレスを指定する(0-63の内、先頭から)
  Wire.write(0x00);
  
  // ---------------------------------
  //  タイマーキーパーレジスタ
  // ---------------------------------
  // 2進化10進数(BCD)で指定します。
  
  // [00]Seconds(56秒)
  Wire.write(0x56);
  // [01]Minutes(34分)
  Wire.write(0x34);
  // [02]Hours(12時)
  Wire.write(0x12);
  // [03]Day(火)
  // 1:日 2:月 3:火 4:水 5:木 6:金 7:土
  Wire.write(0x03);
  // [04]Date(26日)
  Wire.write(0x26);
  // [05]Month(01月)
  Wire.write(0x01);
  // [06]Years(2021年)
  Wire.write(0x21);
 
  // I2Cスレーブへの送信完了
  Wire.endTransmission();

  // OLEDの初期表示
  oled.init();                      // Initialze SSD1306 OLED display
  oled.clearDisplay();              // Clear screen
  oled.setTextXY(1,2);              // Set cursor position, start of line 0
  oled.putString("-----------");
  oled.setTextXY(2,2);              // Set cursor position, start of line 0
  oled.putString("Hello World");
  oled.setTextXY(3,2);              // Set cursor position, start of line 0
  oled.putString("-----------");
}

void loop() {
  // =====  時刻取得 =====
  // レジスタのアドレスを先頭にする
  Wire.beginTransmission(RTC_ADDRESS);
    Wire.write(0x00);
  Wire.endTransmission();
 
  // I2Cスレーブに8byteのレジスタデータを要求する
  Wire.requestFrom(RTC_ADDRESS, 8);
 
  // 8byteのデータを取得する
  for (i = 0; i < 8; i++) {
    while (Wire.available() == 0 ) {}
    RegTbl[i] = Wire.read();
  }
 
  // ----- 現在日時 表示 -----
  sprintf(dispStr,"%04d/%02d/%02d %s",
    BCDtoDec(RegTbl[6]) + 2000,     // 年
    BCDtoDec(RegTbl[5] & 0x1F),     // 月 1~12
    BCDtoDec(RegTbl[4] & 0x3F),     // 日 1~31
    youbi[(RegTbl[3] & 0x07)-1]) ;  // 曜日 (1~7)-1
  oled.setTextXY(5,1);
  oled.putString(dispStr);

  sprintf(dispStr,"%02d:%02d:%02d",
    BCDtoDec(RegTbl[2] & 0x3F),   // 時
    BCDtoDec(RegTbl[1] & 0x7F),   // 分
    BCDtoDec(RegTbl[0] & 0x7F)) ; // 秒
  oled.setTextXY(6,2);
  oled.putString(dispStr);

  delay(100) ;
}